Допомога з перевірки validation rule

Для адміністраторів Validation Rule
1

Перевірте будь ласка ці умови, видає помилку “пропущено дужку”, не можу знайти.

 AND(
            OR(
                   IF( RecordType.DeveloperName = 'Provider',
                      (IF(REGEX(Partner_Provider_Code__c, "{PRV}[^а-яА-Я]" ),FALSE,TRUE),TRUE)),
     	       IF( RecordType.DeveloperName = 'Partner',
    		  (IF(REGEX(Partner_Provider_Code__c, "{PRT}[^а-яА-Я]"),FALSE,TRUE),TRUE))
    	      )
    				 
    	 )
2 
AND(
    OR(
        IF( 
			RecordType.DeveloperName = 'Provider',
			IF(
				REGEX(Partner_Provider_Code__c, "{PRV}[^а-яА-Я]" ),
				FALSE,
				TRUE
			),
			TRUE
		),       
		IF( 
			RecordType.DeveloperName = 'Partner',
			IF(
				REGEX(Partner_Provider_Code__c, "{PRT}[^а-яА-Я]"),
				FALSE,
				TRUE				
			),
			TRUE
		)
    )   				 
)
3 
OR(
        IF( 
			RecordType.DeveloperName = 'Provider',
			NOT(REGEX(Partner_Provider_Code__c, "{PRV}[^а-яА-Я]" )),
			TRUE
		),       
		IF( 
			RecordType.DeveloperName = 'Partner',
			NOT(REGEX(Partner_Provider_Code__c, "{PRT}[^а-яА-Я]")),
			TRUE
		)
    )

Вариант №2, убрал ещё AND() - если это полный вариант функции, то использование AND излишне.

1 Вподобання
4 
CASE(
	RecordType.DeveloperName, 
	'Provider',	
	NOT(REGEX(Partner_Provider_Code__c, "{PRV}[^а-яА-Я]" )),
	'Partner', 
	NOT(REGEX(Partner_Provider_Code__c, "{PRT}[^а-яА-Я]")),
	TRUE
)

Вариант №3. Как по мне самый читабельный

5

Дякую за допомогу

1 Вподобання